//黄鸭：黄昏之星+三只乌鸦+红三兵+早晨之星+倒锤头射击之星
//命名不规范，需要统一命名
//1M（无手续费滑点）铁矿、白银、螺纹 胜率很高
LOTS := INTPART(4000000/(C*MARGIN*UNIT+FEE));//计算开仓手数
TR : MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR : MA(TR, 26);
KTIME:CLOSEMINUTE>15 AND OPENMINUTE>2;
//定义常规K线
KXST:=ABS(O-C);
SYXCD:=H-MAX(O,C);//上影线长度
XYXCD:=MIN(O, C)-L;//下影线长度
YXCD:=H-L;//影线长度
BT:=KXST>YXCD*0.5;//棒体
//定义十字星
SZXST:=KXST<ATR*0.1;//十字星的实体
SZX:=SZXST AND SYXCD>0 AND XYXCD>0;//十字星定义
//早晨之星
//第三天的上涨棒体
ZCZX1:=BT AND YXCD>0.5*ATR AND C=HHV(C,3) AND H>=HHV(H,2);
//第二天的十字星
ZCZX2:=REF(SZX,1) AND REF(L,1)=LLV(L,3) AND REF(H,1)<REF(H,2) ;//早晨之星第二根是星线，最低价为形态最低价
//第一天的下跌棒体
ZCZX3:=REF(BT,2) AND REF(C,2)<REF(C,3) AND REF(YXCD,2)>0.5*ATR;
//定义早晨之星
ZCZX:=ZCZX1 AND ZCZX2 AND ZCZX3;
//黄昏之星
//第三天的下跌棒体
HHZX1:=BT AND YXCD>0.5*ATR AND C<=LV(L,1);
//第二天的十字星
HHZX2:=REF(SZX,1) AND REF(H,1)=HHV(H,3) AND REF(L,1)>REF(L,2);
//第一天的上涨棒体
HHZX3:=REF(BT,2) AND REF(C,2)>REF(C,3) AND REF(YXCD,2)>0.5*ATR;
//定义黄昏之星
HHZX:=HHZX1 AND HHZX2 AND HHZX3 ;
//定义三根阳棒体
SGHBT1:=EVERY(ISUP,3);//三根都是阳线
SGHBT2:=EVERY(BT,3);//三根都是棒体
SGHBT:=SGHBT1 AND SGHBT2;
//定义三根阴棒体
SGYBT1:=EVERY(ISDOWN,3);//三根都是阴线
SGYBT2:=EVERY(BT,3);//三根都是棒体
SGYBT:=SGYBT1 AND SGYBT2;
//定义射击之星
SJZX1:=SYXCD>XYXCD*5;
SJZX2:=SYXCD>KXST;
SJZX3:=C>MA(C,20) AND C>=HHV(C,3);//
SJZX:=SJZX1 AND SJZX2 AND SJZX3 ;
SKXH:=SGHBT OR ZCZX;
BKXH:=SGYBT OR HHZX OR SJZX;
SKXH AND KTIME,SPK(LOTS);//
BKXH AND KTIME,BPK(LOTS);//
NOT(BKXH || SKXH) || C<BKPRICE,SP(BKVOL);//
NOT(BKXH || SKXH) || C>SKPRICE,BP(SKVOL);//
ISLASTKLINE,CLOSEOUT;
|
